home *** CD-ROM | disk | FTP | other *** search
/ C64'er / C64'er.iso / 87xx / 8703a.d64 / geos auf 50hz (.txt) < prev    next >
Commodore BASIC  |  1995-03-30  |  1KB  |  44 lines
  1. 10 REM -- MAKE50HZ ERZEUGT EURO-GEOS --
  2. 15 REM     THORSTEN PETROWSKI 10/86
  3. 20 REM            (C) 64'ER
  4. 25 :
  5. 30 :
  6. 35 A=A+1:IF A=1 THEN LOAD"GDM.OBJ",8,1:REM MASCHINENCODE LADEN
  7. 40 PRINT"[147]GEOS-KERNAL DISK EINLEGEN - TASTE ":REM ANWEISUNG AUSGEBEN
  8. 45 POKE 198,0:WAIT 198,1:REM AUF TASTE WARTEN
  9. 50 :
  10. 55 :
  11. 60 OPEN 15,8,15,"UI":PRINT#15,"IO":REM DISK INITIALISIEREN
  12. 65 OPEN 2,8,2,"GEOS KERNAL":REM GEOS-KERNAL OEFFNEN
  13. 70 :
  14. 75 GOSUB 200:REM DISK-STATUS PRUEFEN
  15. 80 :
  16. 85 SYS 49152:REM RECORDLISTE (VLIR) LESEN
  17. 86 CLOSE2:OPEN2,8,2"#"
  18. 90 :
  19. 95 TR=PEEK(49666):SE=PEEK(49667):REM BLOCK/SEKTOR DES ZWEITEN RECORDS HOLEN
  20. 100 PRINT#15,"B-P:2 0":REM KANAL 2 RUECKSETZEN (AUF 0.BYTE)
  21. 105 :
  22. 110 POKE 53265,11:REM BILDSCHIRM AUS
  23. 115 :
  24. 120 FOR RE=0 TO 16:REM 17 BLOCKS UEBERSPRINGEN
  25. 125 :PRINT#15,"U1:2 0";TR;SE:REM BLOCK NR RE LESEN
  26. 130 :SYS 49152:REM UND IN SPEICHER HOLEN
  27. 135 TA=TR:SA=SE:REM SPUR/SEKTOR MERKEN
  28. 140 TR=PEEK(49664):SE=PEEK(49665):REM UND SPUR/SEKTOR NAECHSTER BLOCK HOLEN
  29. 145 NEXT RE:REM ENDE DER SCHLEIFE
  30. 150 :
  31. 155 POKE 49774,128:REM WERT FUER CIA REGISTER NETZFREQUENZ AUF 50HZ SETZEN
  32. 160 :
  33. 161 PRINT#15,"B-P:2 0"
  34. 165 SYS 49193:PRINT#15,"U2:2 0";TA;SA:REM BLOCK RUECKSCHREIBEN
  35. 170 :
  36. 175 POKE 53265,27:REM BILDSCHIRM WIEDER AN
  37. 180 :
  38. 185 CLOSE 15:CLOSE 2:REM KANAELE SCHLIESSEN
  39. 190 PRINT"GEOS-KERNAL AUF 50HZ TAKT UMGESCHALTET":END:REM MELDUNG AUSGEBEN
  40. 195 :
  41. 200 REM --- DISK-ERROR ---
  42. 205 INPUT#15,EC,E$,T,S:PRINT"DISK:";EC;E$;T;S:REM FEHLERKANAL LESEN
  43. 210 RETURN:REM ZURUECK
  44.